Skip to content

unit InterruptT

ti.mcu.cc23xx/InterruptT.em
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
package ti.mcu.cc23xx

template InterruptT

    config name: string

end

def em$generateUnit(pn, un) 
    auto intrName = name
    auto handlerNameQ = "`" + un + ".handlerName`"
|->>>
    package `pn`

    from ti.mcu.cc23xx import IntrVec

    from em.hal import InterruptSourceI

    module `un`: InterruptSourceI 

    private:
        host var handlerName: string
    end

    def em$construct()
        IntrVec.addIntrH("`intrName`")
    end

    def em$generateCode( prefix )
        if `un`.handlerName
            |-> void `intrName`_Handler() {
            |->     `handlerNameQ`();
            |-> }
        end
    end

    def setHandlerH(h)
        handlerName = h ? ^^String(h).substring(1)^^ : null
    end

    def enable() 
        ^^NVIC_EnableIRQ(`intrName`_IRQn)^^
    end

    def disable() 
        ^^NVIC_DisableIRQ(`intrName`_IRQn)^^
    end

    def clear()
        ^^NVIC_ClearPendingIRQ(`intrName`_IRQn)^^
    end

    def isEnabled() 
        return ^^NVIC_GetEnableIRQ(`intrName`_IRQn)^^
    end
|-<<<
end