Skip to content

unit OneShotSysTick

ti.mcu.cc23xx/OneShotSysTick.em
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
package ti.mcu.cc23xx

import InterruptT { name: "SysTick" } as Intr

import Idle
import Mcu

from em.hal import OneShotMilliI

module OneShotSysTick: OneShotMilliI

private:

    var curArg: ptr_t
    var curFxn: Handler

    function isr: Intr.Handler

end

def em$construct()
    Intr.setHandlerH(isr)
end

def em$startup()
    ^^SysTick->CTRL = SysTick_CTRL_CLKSOURCE_Msk^^
end

def disable()
    curFxn = null
    Idle.setWaitOnly(false)
    Intr.disable()
    ^^SysTick->CTRL &= ~(SysTick_CTRL_TICKINT_Msk | SysTick_CTRL_ENABLE_Msk)^^
end

def enable(msecs, handler, arg)
    curFxn = handler
    curArg = arg
    Idle.setWaitOnly(true)
    Intr.enable()
    ^^SysTick->LOAD^^ = msecs * (Mcu.mclkFrequency / 1000)
    ^^SysTick->CTRL |= SysTick_CTRL_ENABLE_Msk | SysTick_CTRL_TICKINT_Msk^^
end

def isr()
    auto fxn = curFxn
    disable()
    fxn(curArg) if fxn
end