Skip to content

unit Crc16

em.utils/Crc16.em
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
package em.utils

module Crc16

    type Obj: opaque
        function addByte(b: uint8): uint8
        function addData(src: uint8*, len: uint8)
        function getSum(): uint16
        function getSumLsb(): uint8
        function getSumMsb(): uint8
        function init()
    end

    host function createH(): Obj&

private:

    const POLY: uint16 = 0x8005

    def opaque Obj
        sum: uint16
        function update(b: uint8)
    end

end

def createH()
    return new<Obj>
end

def Obj.addByte(b)
    this.update(b)
    return b
end

def Obj.addData(src, len)
    while len--
        this.update(*src++)
    end
end

def Obj.getSum()
    return this.sum
end

def Obj.getSumLsb()
    return <uint8>(this.sum & 0xFF)
end

def Obj.getSumMsb()
    return <uint8>(this.sum >> 8)
end

def Obj.init()
    this.sum = 0xFFFF
end

def Obj.update(b)
    auto tot = this.sum
    for auto i = 0; i < 8; i++
        if ((tot & 0x8000) >> 8) ^ (b & 0x80)
            tot = (tot << 1) ^ POLY
        else
            tot = (tot << 1)
        end
        b <<= 1
    end
    this.sum = tot
end