Skip to content

unit CoreBench

em.coremark/CoreBench.em
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
package em.coremark

from em.lang import Math

import BenchAlgI
import Crc
import ListBench
import IdxComparator
import MatrixBench
import StateBench
import Utils
import ValComparator

module CoreBench: BenchAlgI

    config TOTAL_DATA_SIZE: uint16 = 2000
    config NUM_ALGS: uint8 = 3

end

def em$configure()
    memSize = Math.floor(TOTAL_DATA_SIZE / NUM_ALGS)
    ListBench.idxCompare ?= IdxComparator.compare
    ListBench.valCompare ?= ValComparator.compare
    ListBench.memSize ?= memSize
    MatrixBench.memSize ?= memSize
    StateBench.memSize ?= memSize
    ValComparator.Bench0 ?= StateBench
    ValComparator.Bench1 ?= MatrixBench
end

def em$construct()
    Utils.bindSeedH(1, 0x0)
    Utils.bindSeedH(2, 0x0)
    Utils.bindSeedH(3, 0x66)
end

def dump()
    ListBench.dump()
    MatrixBench.dump()
    StateBench.dump()
end

def kind()
    return Utils.Kind.FINAL
end

def print()
    ListBench.print()
    MatrixBench.print()
    StateBench.print()
end

def run(arg)
    auto crc = ListBench.run(1)
    Utils.setCrc(Utils.Kind.FINAL, Crc.add16(<int16>crc, Utils.getCrc(Utils.Kind.FINAL)))
    crc = ListBench.run(-1)
    Utils.setCrc(Utils.Kind.FINAL, Crc.add16(<int16>crc, Utils.getCrc(Utils.Kind.FINAL)))
    Utils.bindCrc(Utils.Kind.LIST, Utils.getCrc(Utils.Kind.FINAL))
    return Utils.getCrc(Utils.Kind.FINAL)
end

def setup()
    ListBench.setup()
    MatrixBench.setup()
    StateBench.setup()
end